MovieClip steuern

[StoPPeL]

Hallo zusammen...
bin neu hier im Forum, und muss auch zugeben das ich lang nichts mehr mit Flash gemacht habe. Allerdings jetzt wieder ein Projekt, das ich mithilfe von M.K. Flash Bildergallerie gut umsetzen konnte. Mein Prob jetzt ist :
Der MC soll beim Klicken auif die nächste Schaltfläche wieder verschwinden, und die nächste Szene anspielen. Nur leider klappt das nicht so wie ich das will...

Hier der Code:stop ();

// Spalten und Reihen
pS = 1;
pR = 5;
// Limit
max = pS * pR;
// Zweidimensionales Array erzeugen
function setArray (pT)
{
    spielLevel = new Array ();
    for (var m = 0; m < pR; m++)
    {
        spielLevel[m] = [];
        for (var n = 0; n < pS; n++)
        {
            spielLevel[m].push (alleBilder[pT++]);
        }
    }
    tabelle (10, 40, 60, 60);
}
// Movieclips setzen
function tabelle (posX, posY, pB, pW)
{
    for (i in this.mc_bild)
    {
        if (typeof (this.mc_bild[i]) == "movieclip")
        {
            this.mc_bild[i].removeMovieClip ();
        }
    }
    tiefe = 0;
    for (var i = 0; i < spielLevel[0].length; i++)
    {
        for (var j = 0; j < spielLevel.length; j++)
        {
            nName = "block_" + i + "_" + j;
            this.mc_bild.attachMovie ("contclip", nName, tiefe++);
            this.mc_bild[nName].nummer = i;
            this.mc_bild[nName].bildname = "grabsteine/" + spielLevel[j][i];
            this.mc_bild[nName]._x = posX + pB * i * 1.2;
            this.mc_bild[nName]._y = posY + pW * j * 1.2;
            this.mc_bild[nName].onRelease = function ()
            {
                this._parent._parent.createEmptyMovieClip ("inhalt", 10000);
                this._parent._parent.inhalt.attachMovie ("grosscontclip", "grossclip", 1);
                this._parent._parent.inhalt.grossclip.bildname = this.bildname;
                this._parent._parent.inhalt.grossclip._x = 100;
                this._parent._parent.inhalt.grossclip._y = 35;
                this._parent._parent.inhalt.grossclip.leiste_mc.onPress = function ()
                {
                    this._parent.startDrag ();
                };
                this._parent._parent.inhalt.grossclip.leiste_mc.onRelease = this._parent._parent.inhalt.grossclip.leiste_mc.onReleaseOutside = function ()
                {
                    this._parent.stopDrag ();
                };
                this._parent._parent.inhalt.grossclip.leiste_mc.onMouseMove = function ()
                {
                    updateAfterEvent ();
                };
            };
        }
    }
}

var seite:Number = 0;

// Schaltflächen
w_btn.onRelease = function ()
{
    if (seite < alleBilder.length - max)
    {
        seite += max;
        setArray (seite);
    }
};
z_btn.onRelease = function ()
{
    if (seite > 0)
    {
        seite -= max;
        setArray (seite);
    }
};
// Starten
loadVariables ("grabsteine.txt", this);
this.onData = function ()
{
    alleBilder = new Array ();
    alleBilder = bildnamen.split (",");
    createEmptyMovieClip ("mc_bild", 1);
    setArray (0);
};


Wie kann ich die Schaltfläche jetzt mit AS ansetzten ?
(sowas in der Art wie unloadMovie, oder removeMovieClip)

on (release) {
         gotoAndPlay("Designobjekte", 1);
}

.:St3ff3N:.

 

[Jens B.]

Hi!

Was genau meinst du mit "ansetzen" Wenn ich das ganze jetzt nicht komplett falsch interpretiere (und irgendwie glaub ich, ich tu das grad ;-] ) sollte für deine Zwecke ein einfaches _visible=false bzw. true reichen...

Gruß,
Jens

 

[StoPPeL]

Ähmmmmmm.
Also das ganze ist eine Bildgalerie wie bereits gesehen (denke ich).
Beim Klick auf eine Schaltfläche soll nun diese Galerie geschlossen werden und in eine neue Szene gesprungen werden. Teilweise gibt es dort auch noch Galerien. Am liebsten (und einfachsten) wäre das ganze mit >unload< ?!

Momentan auf der schaltfläche liegender AS:
on(release){
unloadMovie(inhalt);
unloadMovie(mc_bild);
gotoandPlay("Designobjekte",1)
}

Allerdings stopt der Film beim testen und sagt "Film nicht geladen"

.:St3ff3N:.

 

[Tobias Menzel]

... kannst Du die Datei einmal posten?
.

 

[StoPPeL]

leider zu groß (3.6 MB) zum posten. Ich lege sie daher mal auf den Server....
Steinbildhauerei- Gräf
Die Bildgalerie soll verschwinden wenn man auf einen anderen Button klickt.

Die Fla liegt hier

Hoffe das wir des gemeinsam hinbekommen

.:St3ff3N:.

 

[StoPPeL]

gelöst:
für Leute mit ähnlichem Problem hier nochmal die Zusammenfassung:
im RootBild das AS mit:
function loeschen (nSzene)
{
//loescht das große Bild
inhalt.removeMovieClip ();
for (var i = 0; i < spielLevel[0].length; i++)
{
for (var j = 0; j < spielLevel.length; j++)
{
nName = "block_" + i + "_" + j;
//die kleinen bilder
this.mc_bild[nName].removeMovieClip ();
}
}
switch (nSzene)
{
case "Grabsteine" :
gotoAndPlay ("Grabsteine", 1);
break;
case "Startseite" :
gotoAndPlay ("Startseite", 1);
break;
case "Person" :
gotoAndPlay ("Person", 1);
break;
case "Designobjekte" :
gotoAndPlay ("Designobjekte", 1);
break;
case "Gartenmöbel" :
gotoAndPlay ("Gartenmöbel", 1);
break;
case "Skulpturen" :
gotoAndPlay ("Skulpturen", 1);
break;
case "Gemälde" :
gotoAndPlay ("Gemälde", 1);
break;
case "Kurse" :
gotoAndPlay ("Kurse", 1);
break;
}
}
ergänzen und der Schaltfläche dann folgendem AS zuordnen:
on (release) {
_root.loeschen("Designobjekte");
}


-_St3ff3N-_