Klasse in AS...

[SonMiko]

Hallo liebe Leute,

ich stehe mal wieder vor einem Rätsel ...
Hier meine Klasse:

class Kugel extends MovieClip{
	
	var startzeit:Number=getTimer();
	var zufallx:Number;
	var zufally:Number;
	function Kugel(){
		setInterval(countdown,1000);
		zufallx=random(600);
		zufally=random(400);
		onEnterFrame=function(){
		_x+=(zufallx-_x)/25;
		_y+=(zufally-_y)/25;
	}
	var zeitstart:Number=3;
	var zeit:Number=zeitstart;
	function countdown(){
		trace(zeit);
		if(zeit==0){
		zufallx=random(600);
		zufally=random(400);
		zeit=zeitstart;
		}
		else{
			zeit--;
		}
	}
}
}

Alles läuft wunderbar - NUR werden die werte aus der Funktion "countdown" NICHT an die
"onEnterFrame" Methode übergeben, so das das entsprechende Objekt also quasi einmalig eine schöne Bewegung aufs Parkett liegt, dann aber verharrt - bei Ausgabe ist der "random Wert" "undefined".
Woran liegt das? Gilt der Wert denn oberhalb nicht mehr?


UPDATE:

Ich habe das Problem soeben lösen können, indem ich die Variablen erneut über die Funktion schrieb - aber wieso geraten sie sonst in "Vergessenheit" oder darf Flash nicht darauf zugreifen
Mit "public" ging es auch nicht...
Hier der Code...

class Kugel extends MovieClip{
	
	var startzeit:Number=getTimer();
	var zufallx:Number;
	var zufally:Number;
	public function Kugel(){
		setInterval(countdown,1000);
		zufallx=random(600);
		zufally=random(400);
		onEnterFrame=function(){
		_x+=(zufallx-_x)/25;
		_y+=(zufally-_y)/25;
	}
	
	var zeitstart:Number=3;
	var zeit:Number=zeitstart;
	var zufallx:Number;
	var zufally:Number;
	function countdown(){
		trace(zeit);
		if(zeit==0){
		zufallx=random(600);
		zufally=random(400);
		trace(zufallx);
		zeit=zeitstart;
		}
		else{
			zeit--;
		}
	}
	
}
}

Besten Gruß,

Mike

 

[Tobias Menzel]

Hi,

beim Aufruf der setInterval-Methode geht Dir die Referenz auf die lokale Klasseninstanz verloren. Zudem ist "countdown" kein persistenterKlassenmember, sondern eine lokale Submethode der Methode "Kugel".

Probiers mal so:

class Kugel extends MovieClip{
	private var startzeit:Number = getTimer();
	private var zeitstart:Number;
	private var zeit:Number;
	private var zufallx:Number;
	private var zufally:Number;
	private var iv:Number;
	
	public function Kugel() {
		zeitstart = 3;
		zeit = zeitstart;
		iv = setInterval(this, "countdown", 1000);
		zufallx = random(600);
		zufally = random(400);
		this.onEnterFrame=function(){
			_x += (zufallx - _x) / 25;
			_y += (zufally - _y) / 25;
		}
	}
	private function countdown():Void {
		trace(zeit);
		if(zeit == 0){
		zufallx = random(600);
		zufally = random(400);
		zeit = zeitstart;
		} else {
			zeit--;
		}
	}
}

Gruß
.