✔ Excel Zelle nach einem Wort durchsuchen

[Sissi_KK]

Hallo,

ich hab ein Problem mit Excel. Ich möchte aus einer Zelle in der mehrere Worte in Klammern stehen auf ein Wort untersuchen und dafür dann eine Zahl ausgeben lassen.
Beispiel: in der ersten Zelle steht: "(Blume, Pferd, Haus)" nun möchte ich in der zweiten Zelle, das wenn das Wort Blume auftaucht, eine "1" steht.
Hab das mit WENN("Blume";"1";"") probiert, aber da ja mehrere Wörter drin stehen untersucht es Excel mir nicht.
Was muss ich eingeben das es funktioniert?
Danke im voraus für Eure antworten.

Gruß Philip

 

[illuzione]

Hallo,

=WENN(NICHT(ISTFEHLER(SUCHEN(A1;A2;1)));"Gefunden";"Nicht gefunden")

Das müsste funktionieren.

Funktion sucht A1 in meinem Fall "Pferd" in A2. A2 war in meinem Fall "Hund,Katze,Maus,Pferd,Panda".

Wenn er das Wort in der Zelle gefunden hat schreibt er "gefunden" und wenn er es nicht gefunden hat "nicht gefunden".

Gruß,
Jens

 

[maxili]

das ist super schonmal.
aber wie macht man das ganze jetzt, wenn man 1000 solcher zellen hat und zählen möchte in wievielen zellen beispielsweise "Pferd" vorkommt?
dachte dasselbe einfach mit SUMMEWENN anstatt mit WENN, aber ganz so einfach ist es nicht
Für Hilfe wäre ich jedenfalls sehr dankbar!

 

[tombe]

Wenn du in dieser Formel aus XX:XX deinen Bereich machst, werden alle Einträge gezaählt bei denen Gefunden angezeigt wird.

=ZÄHLENWENN(XX:XX;"Gefunden")

 

[maxili]

Herzlichen Dank, aber ich brauche das in einem... sprich ich möchte nicht das Hilfskonstrukt "Gefunden" verwenden. Abgesehen davon, dass es auch nicht geht, weil ich nicht nur "Pferd", sondern auch "Hund","Katze","Maus" etc... zählen möchte.
Dann müsste ich für jedes Tier einzeln ja nochmal über das Hilfskonstrukt "Gefunden" gehen.

 

[tombe]

Ok, dann eben so:

=ZÄHLENWENN($A1:$A10; "*" & $A15 & "*")

Die Werte stehen in den Zellen "A1" bis "A10" und in Zelle "A15" geben ich den gesuchten Begriff ein.

 

[maxili]

Besten Dank!
Und jetzt noch das i-Tüpfelchen...
Ich habe eine weitere Spalte wo drinsteht Zoo bzw. Bauernhof, etc...
Jetzt will ich beispielsweise von den Zootieren alle Pferde zählen.

sprich es müsste wie folgt sein:

=ZÄHLENWENN ($A1:$A10; "*" & $A15 & "*") in Abhängigkeit, dass in den Zellen "B1" bis "B10" "Zoo" steht...

wenn du mir jetzt noch helfen könntest, wäre ich restlos zufrieden und wenn du nach Frankfurt kommst, geb ich dir auch ein bierchen aus, wenn du magst.

 

[tombe]

Hab zwar noch keine Lösung aber ich fahre schonmal los!!

Nein, Spaß beiseite. Wie muss ich mir das mit der Verknüpfung von z.B. Zoo und Pferd verstehen.

Gibt es Zeilen wo

(Blume, Pferd, Haus) - Zoo

steht und in einer anderen Zeile steht

(Blume, Pferd, Haus) - Bauernhof

 

[maxili]

Genau. Und jetzt sollen in dem einen Fall nur Blumen in Zoos gezählt werden.

Es geht zwar nicht um Tiere und Zoos aber zum Verständnis reichts ja.
Ich will wissen welchen Anteil Blumen speziell im Bereich von Zoos (und nicht insgesamt, sprich nicht auch noch in den anderen Bereichen) einnehmen.

Und schonmal echt besten Dank für die schnelle Hilfe. Schöne Grüße aus FFM

 

[tombe]

=SUMMENPRODUKT((ISTZAHL(FINDEN($A15;A1:A10))*(B1:B10=$A16)))

Also in den Zellen "A1" bis "A10" stehen Hund, Katze, Maus. In den Zellen "B1" bis "B10" steht entsprechend "Zoo", "Bauernhof", ...

In Zelle "A15" steht zum Beispiel Pferd und in Zelle "A16" steht Zoo.

So jetzt stellst du aber wirklich das Bier kalt!