Anfängerfrage (ActionSkript: Movieclip Steuern)

[fryfan]

Ehrlichgesagt hab ich von dem ActionSkript keine ahnung...hab erst mit Flash angefangen.
Ich hab gemacht das wenn ich mit der Maus über ein Text gehe ein Bild in das einfährt.
Geht ja ziemlich einfach, ohne irgendwelches Programmieren im ActionSkript.
Aber nun hätte ich gerne das dieses Bild wenn ich mit der Maus vom Text heruntergehe nicht einfach verschwindet sondern auch wieder ausfährt.

Das ganze müsste ich ja irgendwie mit einem ActionSkript machen können.

Nur wie?
Und bitte nicht nur die Befehlszeilen Posten...Mein problem ist nämlich WO (also in dem Text oder bei dem Bild) ich diese einfügen muss...
Sprich: Ich hab keine Ahnung von ActionSkript

Schonmal danke im vorraus

 

[Rena Hermann]

Eine Möglichkeit unter vielen:

Du brauchst
- einen Movieclip, der als Button fungiert. Dieser bekommt den Instanznamen "buttonmc"
- einen Movieclip, der ein- und ausgeblendet werden soll. Dieser bekommt den Instanznamen "einblender"

Beide legst du auf die Bühne und im selben Frame (ggf. auf einer anderen Ebene) kommt dieses Script

//zunächst das was eingeblendet werden soll, auf transparent setzen
einblender._alpha=0
//Script für den Button-Movieclip beim Drüberfahren
buttonmc.onRollOver=function(){
	//dem einzublendenen Movieclip ein "Dauerscript" (onEnterFrame) zuweisen
	this._parent.einblender.onEnterFrame=function(){
		// Einblenden bis volle Deckkraft
		this._alpha+=(100-this._alpha)/10; //je kleiner die Zahl umso schneller
	}
}
//Script für den Button-Movieclip beim Rausfahren
buttonmc.onRollOut=function(){
	//dem einzublendenen Movieclip ein "Dauerscript" (onEnterFrame) zuweisen
	this._parent.einblender.onEnterFrame=function(){
		// Ausblenden in Transparenz 
		this._alpha+=(0-this._alpha)/10;
		// Zur Schonung der Performance und wenn die Transparenz quasi da ist
		// wenn die Deckkraft < 2% ist
		if(this._alpha < 2) {
			// die Deckkraft vollständig auf 0 setzen
			this._alpha=0
			// den enterFrame-Event löschen, da der sonst bis zum
			// Sankt-Nimmerleins-Tag ausgeführt wird.
			delete this.onEnterFrame;
		}
	}
}
// wenn auch in diesem Frame der Film anhalten soll
stop();

Wie gesagt - eine Möglichkeit von vielen.
Ein Beispiel findest du im Anhang (ab FlashMX)

Gruß
Rena