✔ Sammel Thread und Flash-FAQ

var myloadvars = new LoadVars();

myloadvars.load("textdatei.txt");

myloadvars.onLoad = function(success) {
    if (success) {
        trace(this.variable1); // Zugriff auf alle Variablen über ihren Bezeichner
    } else {
        trace("Fehlermeldung");
    }
}

myloadvars = new LoadVars();

myloadvars.foo = "Bla";
myloadvars.bar = "Blubb"; 

myloadvars.sendAndLoad("test.php", myloadvars, "POST");
// sendAndLoad kann im selben Aufruf auch die Ausgabe des Scriptes empfangen.
// Man übergibt der Methode das empfangende LoadVars-Objekt (hier das selbe).
myloadvars.onLoad = function(sucess) {
    if (sucess) {
        trace(this.response); // Scriptausgabe z.B. echo("response=Hallo");
    } else {
        trace("Fehlermeldung");
    }
}

MovieClip.prototype.setSound = function(sname) {
	if (this.s_container == undefined) this.s_container = this.createEmptyMovieClip("s_container", this.getNextHighestDepth());
	var new_snd = this.s_container.createEmptyMovieClip(sname, this.s_container.getNextHighestDepth());
	new_snd.snd = new Sound(new_snd);
	new_snd.snd.attachSound(sname);
}

MovieClip.prototype.playSound = function(sname, vol, pan, offset, restart, loop) {
	if (this.s_container[sname] != undefined) {
		var snd = this.s_container[sname].snd;
		if (offset == undefined) offset = 0;
		if (pan == undefined) pan = snd.getPan();
		if (vol == undefined) vol = snd.getVolume();
		if (restart) snd.stop();
		snd.setPan(pan);
		snd.setVolume(vol);
		if (loop) {
			snd.onSoundComplete = function() {
				this.start(offset);
			}
		} else {
			delete snd.onSoundComplete;
		}
		snd.start(offset);
	}
}

MovieClip.prototype.stopSound = function(sname) {
	this.s_container[sname].snd.stop();
}

MovieClip.prototype.adjustSound = function(sname, vol, pan) {
	if (pan == undefined) pan = this.s_container[sname].snd.getPan();
	if (vol == undefined) vol = this.s_container[sname].snd.getVolume();
	this.s_container[sname].snd.setPan(pan);
	this.s_container[sname].snd.setVolume(vol);
}